Math 331.1 •  Fall 2005

Beats & resonance

Copyright © 2005 Murray Eisenberg.  All rights reserved.

Notation

The first two cells allow using a subscript on (Subscript[ω, 0])for denoting the natural frequency

Needs["Utilities`Notation`"]

Notation[(Subscript[ω, 0]) ⟺ ω0]

Undamped harmonic oscillator with no forcing and natural frequency ((Subscript[ω, 0])/(2  π)) = 263:  middle C

middleC  =  
      First@DSolve[{y''[t]  +  ((Subscript[ω, 0])^2) y[t]  ==  0,  
              y[0]  ==  0,  y'[0]  ==  1},  y[t],  
            t]  /.  (Subscript[ω, 0])  ->  2 π 263

Plot[
        Evaluate[y[t]  /.  middleC],  {t,  
          0,  (1/200) 2  π}];

Plot[
        Evaluate[y[t]  /.  middleC],  {t,  0,  (8/5) 2  π},  
        PlotPoints  ->  500];

After you see a graphic representation of the Play result of the next cell, you will hear the sound.  (To hear the sound again, click on the speaker-like icon.)

Play[
        Evaluate[y[t]  /.  middleC],  {t,  
          0,  (8/5) 2  π}];

Undamped harmonic oscillator with sinusoidal forcing of frequency (ω/(2  π)) ≈ ((Subscript[ω, 0])/(2  π)):  beating

beat  =  First@
          DSolve[{y''[t]   +   ((Subscript[ω, 0])^2) y[t]  ==  
                Cos[ω t],  y[0]  ==  y'[0]  ==  0},  
            y[t],  t] /. {(Subscript[ω, 0])  ->  
            2 π 263,  ω   ->  
            2 π (263  + (2/10))}

Plot[y[t]  /.  beat,  {t,  0,  (1/200) 2  π},  
        PlotPoints  ->  150];

Plot[y[t]  /.  beat,  {t,  0,  (8/5) 2  π},  
        PlotPoints  ->  500];

Play[
        Evaluate[y[t]  /.  beat],  {t,  
          0,  (8/5) 2  π}];

Hearing beats more easily

It's easier to hear the beats when the forcing frequency is not quite so close to the natural frequency:

beat  =  
        First@DSolve[{y''[t]   +   ((Subscript[ω, 0])^2) y[t]  ==  
                  Cos[ω t],  y[0]  ==  y'[0]  ==  0},  
              y[t],  t]  /.  {(Subscript[ω, 0])  ->  
              2 π 263,  ω   ->  
              2 π (263  + 1)} ;
Play[
        Evaluate[y[t]  /.  beat],  {t,  
          0,  (8/5) 2  π}];

beat  =  
        First@DSolve[{y''[t]   +   ((Subscript[ω, 0])^2) y[t]  ==  
                  Cos[ω t],  y[0]  ==  y'[0]  ==  0},  
              y[t],  t]  /.  {(Subscript[ω, 0])  ->  
              2 π 263,  ω   ->  
              2 π (263  + 5)} ;
Play[
        Evaluate[y[t]  /.  beat],  {t,  
          0,  (8/5) 2  π}];

beat  =  
        First@DSolve[{y''[t]   +   ((Subscript[ω, 0])^2) y[t]  ==  
                  Cos[ω t],  y[0]  ==  y'[0]  ==  0},  
              y[t],  t]  /.  {(Subscript[ω, 0])  ->  
              2 π 263,  ω   ->  
              2 π (263  + 10)} ;
Play[
        Evaluate[y[t]  /.  beat],  {t,  
          0,  (8/5) 2  π}];

Understanding beats

soln  =  
      First@DSolve[{y''[t]   +   ((Subscript[ω, 0])^2) y[t]  ==  
                Cos[ω  t],  y[0]  ==  y'[0]  ==  0},  
            y[t],  t]  //  Simplify

α  =  (1/2) (ω  +  (Subscript[ω, 0]));  
    β  =  (1/2) (ω  -  (Subscript[ω, 0]));

(2/((ω^2) -  ((Subscript[ω, 0])^2))) Sin[α t] 
        Sin[β t]  //  Simplify

(y[t]  /.  soln)  ==  
        (2/((ω^2) -  ((Subscript[ω, 0])^2))) Sin[α t] 
          Sin[β t]  //  Simplify

(2/((ω^2) -  ((Subscript[ω, 0])^2))) Sin[α t] 
      Sin[β t]

Undamped harmonic oscillator with sinusoial forcing of frequency (ω/(2  π)) =  natural frequency ((Subscript[ω, 0])/(2  π)): resonance

newTone  =  
      First@DSolve[{y''[t]  +  ((Subscript[ω, 0])^2) y[t]  ==  
                Cos[(Subscript[ω, 0])  t],  
              y[0]  ==  0,  y'[0]  ==  1},  y[t],  
            t]  /.  (Subscript[ω, 0])  ->  2 π 263

Plot[
        Evaluate[y[t]  /.  newTone],  {t,  
          0,  (1/20) 2  π}];

Plot[
        Evaluate[y[t]  /.  newTone],  {t,  0,  (8/5) 2  π},  
        PlotPoints  ->  500];

After you see a graphic representation of the Play result of the next cell, you will hear the sound.  (To hear the sound again, click on the speaker-like icon.)

Play[
        Evaluate[y[t]  /.  newTone],  {t,  0,  (8/5) 2  π},  
        PlayRange  ->  All];