/////////////////////////////////////////////////////
//
// Tertiary Burniat surface with K^2=3
//
/////////////////////////////////////////////////////

X:=rec<Surface|>;

Pic:=LatticeWithGram(DiagonalMatrix([1,-1,-1,-1,-1,-1,-1]):
                        CheckPositive := false); // allows neg-def

n:=[2:i in [1..5]];
Gt:=AbelianGroup(n);
G:=sub<Gt|Gt.1,Gt.2>;
T:=sub<Gt|Gt.3,Gt.4,Gt.5>;

X`Name:="Burniat 3 nodal";

X`Big:=Gt;
X`Small:=G;
X`Tors:=T;

X`branch:=[
Pic![1,-1,-1,0,0,0,0],Pic![1,-1,0,0,-1,-1,0],Pic![1,-1,0,0,0,0,-1], // A_i
Pic![1,0,-1,-1,0,0,0],Pic![1,0,-1,0,-1,0,-1],Pic![1,0,-1,0,0,-1,0], // B_i
Pic![1,-1,0,-1,0,0,0],Pic![1,0,0,-1,0,-1,-1],Pic![1,0,0,-1,-1,0,0], // C_i
Pic![0,1,0,0,0,0,0],Pic![0,0,1,0,0,0,0],Pic![0,0,0,1,0,0,0]]; // E_i

X`phi:=[Gt.1,Gt.1+Gt.3,Gt.1+Gt.4,
        Gt.2,Gt.2+Gt.5,Gt.2+Gt.3+Gt.4+Gt.5,
        Gt.1+Gt.2+Gt.3+Gt.4,Gt.1+Gt.2+Gt.4+Gt.5,Gt.1+Gt.2+Gt.3+Gt.5];
X`phi[10]:=X`phi[1]+X`phi[2]+X`phi[3]+X`phi[7];
X`phi[11]:=X`phi[4]+X`phi[5]+X`phi[6]+X`phi[1];
X`phi[12]:=X`phi[7]+X`phi[8]+X`phi[9]+X`phi[4];


X`branchtors:=[T![1,1,0],T![1,0,1],T![1,1,0],
               T![0,0,1],T![1,0,1],T![0,0,1],
               T!0,T![1,0,1],T!0,
               T!0,T!0,T!0];

X`KY:=Pic![-3,1,1,1,1,1,1];
X`K:=Pic![3,-1,-1,-1,-1,-1,-1];

lines:=#X`branch;

X`Lchi:=calculateLchi(X);

// find torsion twists...

X`Basis:=[[0,0,0,0,0,0,1,0,0,1,0,1],
        [0,0,0,0,0,0,0,0,0,1,0,0],
        [0,0,0,0,0,0,0,0,0,0,1,0],
        [0,0,0,0,0,0,0,0,0,0,0,1],
        [0,0,0,0,0,0,1,0,-1,1,0,0],
        [0,0,0,1,0,-1,0,0,0,0,0,1],
        [1,0,-1,0,0,0,0,0,0,0,1,0]];


findCoordinates(X,[1,0,0,0,0,0,0,0,0,0,0,0]);

X`Ktors:=T![1,0,1];

// random approach to effective divisors loads a bit faster

// -1 curves on the degree 3 weak dP
CC:=[Pic.i:i in [2..7]] cat
    &cat[[Pic.1-Pic.i-Pic.j:i in [j+1..7]]:j in [2..7]] cat
    [Pic![2,-1,-1,-1,-1,-1,-1]+Pic.i:i in [2..7]];
// -2 curves on the degree 3 weak dP
Append(~CC,Pic![1,-1,0,0,-1,-1,0]);
Append(~CC,Pic![1,0,-1,0,-1,0,-1]);
Append(~CC,Pic![1,0,0,-1,0,-1,-1]);
EffY:={c:c in CC};

A:=CartesianProduct([[0..1]:i in [1..#CC]]);
for i in [1..250000] do
   a:=Random(A);
   Include(~EffY,&+[a[i]*CC[i]:i in [1..#CC]]);
end for;
// random approach is faster, but requires a few additional curves to be included
Include(~EffY,Pic.1);
Include(~EffY,Pic!0);

X`EffY:=EffY;

////////////////////

LL:=[Pic![0,-1,0,0,0,0,0],Pic![0,0,-1,0,0,0,0],Pic![0,0,0,-1,0,0,0],
     Pic![0,0,0,0,-1,0,0],Pic![0,0,0,0,0,-1,0],Pic![0,0,0,0,0,0,-1],
     Pic![-1,0,0,0,0,0,0],Pic![-2,0,0,0,0,0,0]]; // "standard"

LL:=[-Pic.2+Pic.5,-Pic.2,-Pic.1+Pic.3+Pic.5,-Pic.1+Pic.5+Pic.6,-Pic.1+Pic.5,
     -2*Pic.1+Pic.3+Pic.4+Pic.5+Pic.6,-2*Pic.1+Pic.3+Pic.5+Pic.6+Pic.7,
     -2*Pic.1+Pic.3+Pic.5+Pic.6]; // 3*A2 toric

simpleroots:=[Pic.1-Pic.2-Pic.3-Pic.4,Pic.2-Pic.3,Pic.3-Pic.4,Pic.4-Pic.5,Pic.5-Pic.6,Pic.6-Pic.7];

LL:=[Weylreflection(X,L,simpleroots[2]):L in LL];
time Excl:=findExceptional(X,LL); // found 21 from 933120


ee:=< T.3, T.2 + T.3, T.1, T.2 + T.3, T.3, T.1 + T.2, T!0, T.2 >;


ee in Excl; // true

H,E:=findHoms(X,LL,ee);
[H[[i,j]]:i in [j+1..#LL],j in [0..#LL]];