/////////////////////////////////////////////////////
//
// Secondary Burniat surface with K^2=4 (nodal)
//
/////////////////////////////////////////////////////

X:=rec<Surface|>;

Pic:=LatticeWithGram(DiagonalMatrix([1,-1,-1,-1,-1,-1]):
                        CheckPositive := false); // allows neg-def

n:=[2:i in [1..6]];
Gt:=AbelianGroup(n);
G:=sub<Gt|Gt.1,Gt.2>;
T:=sub<Gt|Gt.3,Gt.4,Gt.5,Gt.6>;

X`Name:="Burniat 4 nodal";

X`Big:=Gt;
X`Small:=G;
X`Tors:=T;

X`branch:=[
Pic![1,-1,-1,0,0,0],Pic![1,-1,0,0,-1,-1],Pic![1,-1,0,0,0,0], // A_i
Pic![1,0,-1,-1,0,0],Pic![1,0,-1,0,-1,0],Pic![1,0,-1,0,0,-1], // B_i
Pic![1,-1,0,-1,0,0],Pic![1,0,0,-1,0,-1],Pic![1,0,0,-1,-1,0], // C_i
Pic![0,1,0,0,0,0],Pic![0,0,1,0,0,0],Pic![0,0,0,1,0,0]]; // E_i

X`phi:=[Gt.1,Gt.1+Gt.3,Gt.1+Gt.4,
        Gt.2,Gt.2+Gt.5,Gt.2+Gt.6,
        Gt.1+Gt.2+Gt.3+Gt.4,Gt.1+Gt.2+Gt.3+Gt.6,Gt.1+Gt.2+Gt.3+Gt.5];
X`phi[10]:=X`phi[1]+X`phi[2]+X`phi[3]+X`phi[7];
X`phi[11]:=X`phi[4]+X`phi[5]+X`phi[6]+X`phi[1];
X`phi[12]:=X`phi[7]+X`phi[8]+X`phi[9]+X`phi[4];


X`branchtors:=[T![1,1,0,0],T![1,0,1,0],T![0,1,0,0],
               T![0,0,1,1],T![0,0,1,0],T![0,0,1,1],
               T!0,T![0,0,1,0],T!0,
               T!0,T!0,T!0];

X`KY:=Pic![-3,1,1,1,1,1];
X`K:=Pic![3,-1,-1,-1,-1,-1];

lines:=#X`branch;

X`Lchi:=calculateLchi(X);

// find torsion twists...

X`Basis:=[[0,0,0,0,0,0,1,0,0,1,0,1],
        [0,0,0,0,0,0,0,0,0,1,0,0],
        [0,0,0,0,0,0,0,0,0,0,1,0],
        [0,0,0,0,0,0,0,0,0,0,0,1],
        [0,0,0,0,0,0,1,0,-1,1,0,0],
        [0,0,0,1,0,-1,0,0,0,0,0,1]];


findCoordinates(X,[1,0,0,0,0,0,0,0,0,0,0,0]);

X`Ktors:=T![0,0,1,0];


// -1 curves on the degree 4 weak dP
CC:=[Pic.i:i in [2..6]] cat
    &cat[[Pic.1-Pic.i-Pic.j:i in [j+1..6]]:j in [2..6]] cat
    [Pic![2,-1,-1,-1,-1,-1]];
// -2 curves on the degree 4 weak dP
Append(~CC,Pic![1,-1,0,0,-1,-1]);
EffY:={};
for a in CartesianProduct([[0..1]:i in [1..#CC]]) do
   Include(~EffY,&+[a[i]*CC[i]:i in [1..#CC]]);
end for;
X`EffY:=EffY;


LL:=[Pic![0,-1,0,0,0,0],Pic![0,0,-1,0,0,0],Pic![0,0,0,-1,0,0],
     Pic![0,0,0,0,-1,0],Pic![0,0,0,0,0,-1],
     Pic![-1,0,0,0,0,0],Pic![-2,0,0,0,0,0]]; // "standard"

time Excl:=findExceptional(X,LL); // found 13 from 12196800

ee:=<T.1 + T.3, T.2 + T.4, T.3 + T.4, T.2 + T.3, 0, T.2 + T.4, T.1 + T.3 + T.4>;

ee in Excl;

H,E:=findHoms(X,LL,ee);
//[H[[i,j]]:i in [j+1..#LL],j in [0..#LL]];